Chapter 21. Formal Grammars

21.1. EBNF Grammar of Lojban

Lojban Machine Grammar, EBNF Version, Final Baseline

This EBNF document is explicitly dedicated to the public domain by its author, The Logical Language Group, Inc. Contact that organization at: 2904 Beau Lane, Fairfax VA 22031 USA 703-385-0273 (intl: +1 703 385 0273)

Explanation of notation: All rules have the form:

name _number = bnf-expression

which means that the grammatical construct “name” is defined by “bnf-expression” .

Names in lower case are grammatical constructs.
Names in UPPER CASE are selma'o (lexeme) names, and are terminals.
Concatenation is expressed by juxtaposition with no operator symbol.
| represents alternation (choice).
[] represents an optional element.
& represents and/or. “A & B” is the same as “A | B | A B” but not “B A” . Furthermore, “A & B & C & D” permits one or more of A, B, C, and/or D, but only in that order.
... represents optional repetition of the construct to the left. Left-grouping is implied; right-grouping is shown by explicit self-referential recursion with no “...”
() serves to indicate the grouping of the other operators. Otherwise, “...” binds closer than &, which binds closer than |.
# is shorthand for “[free ...]” , a construct which appears in many places.
// encloses an elidable terminator, which may be omitted (without change of meaning) if no grammatical ambiguity results.

text ₀ =: [NAI ...] [CMEVLA ... # | (indicators & free ...)] [joik-jek] text-1
text-1 ₂ =: [(I [jek | joik] [[stag] BO] #) ... | NIhO ... #] [paragraphs]
paragraphs ₄ =: paragraph [NIhO ... # paragraphs]
paragraph ₁₀ =: (statement | fragment) [I # [statement | fragment]] ...
statement ₁₁ =: statement-1 | prenex statement
statement-1 ₁₂ =: statement-2 [I joik-jek [statement-2]] ...
statement-2 ₁₃ =: statement-3 [I [jek | joik] [stag] BO # [statement-2]]
statement-3 ₁₄ =: sentence | [tag] TUhE # text-1 /TUhU#/
fragment ₂₀ =: ek # | gihek # | quantifier | NA # | terms /VAU#/ | prenex | relative-clauses | links | linkargs
prenex ₃₀ =: terms ZOhU #
sentence ₄₀ =: [terms [CU #]] bridi-tail
subsentence ₄₁ =: sentence | prenex subsentence
bridi-tail ₅₀ =: bridi-tail-1 [gihek [stag] KE # bridi-tail /KEhE#/ tail-terms]
bridi-tail-1 ₅₁ =: bridi-tail-2 [gihek # bridi-tail-2 tail-terms] ...
bridi-tail-2 ₅₂ =: bridi-tail-3 [gihek [stag] BO # bridi-tail-2 tail-terms]
bridi-tail-3 ₅₃ =: selbri tail-terms | gek-sentence
gek-sentence ₅₄ =: gek subsentence gik subsentence tail-terms | [tag] KE # gek-sentence /KEhE#/ | NA # gek-sentence
tail-terms ₇₁ =: [terms] /VAU#/
terms ₈₀ =: terms-1 ...
terms-1 ₈₁ =: terms-2 [PEhE # joik-jek terms-2] ...
terms-2 ₈₂ =: term [CEhE # term] ...
term ₈₃ =: sumti | (tag | FA #) (sumti | /KU#/) | termset | NA KU #
termset ₈₅ =: NUhI # gek terms /NUhU#/ gik terms /NUhU#/ | NUhI # terms /NUhU#/
sumti ₉₀ =: sumti-1 [VUhO # relative-clauses]
sumti-1 ₉₁ =: sumti-2 [(ek | joik) [stag] KE # sumti /KEhE#/]
sumti-2 ₉₂ =: sumti-3 [joik-ek sumti-3] ...
sumti-3 ₉₃ =: sumti-4 [(ek | joik) [stag] BO # sumti-3]
sumti-4 ₉₄ =: sumti-5 | gek sumti gik sumti-4
sumti-5 ₉₅ =: [quantifier] sumti-6 [relative-clauses] | quantifier selbri /KU#/ [relative-clauses]
sumti-6 ₉₇ =: (LAhE # | NAhE BO #) [relative-clauses] sumti /LUhU#/ | KOhA # | lerfu-string /BOI#/ | LA # [relative-clauses] CMEVLA ... # | (LA | LE) # sumti-tail /KU#/ | LI # mex /LOhO#/ | ZO any-word # | LU text /LIhU#/ | LOhU any-word ... LEhU # | ZOI any-word anything any-word #
sumti-tail ₁₁₁ =: [sumti-6 [relative-clauses]] sumti-tail-1 | relative-clauses sumti-tail-1
sumti-tail-1 ₁₁₂ =: [quantifier] selbri [relative-clauses] | quantifier sumti
relative-clauses ₁₂₁ =: relative-clause [ZIhE # relative-clause] ...
relative-clause ₁₂₂ =: GOI # term /GEhU#/ | NOI # subsentence /KUhO#/
selbri ₁₃₀ =: [tag] selbri-1
selbri-1 ₁₃₁ =: selbri-2 | NA # selbri
selbri-2 ₁₃₂ =: selbri-3 [CO # selbri-2]
selbri-3 ₁₃₃ =: selbri-4 ...
selbri-4 ₁₃₄ =: selbri-5 [joik-jek selbri-5 | joik [stag] KE # selbri-3 /KEhE#/] ...
selbri-5 ₁₃₅ =: selbri-6 [(jek | joik) [stag] BO # selbri-5]
selbri-6 ₁₃₆ =: tanru-unit [BO # selbri-6] | [NAhE #] guhek selbri gik selbri-6
tanru-unit ₁₅₀ =: tanru-unit-1 [CEI # tanru-unit-1] ...
tanru-unit-1 ₁₅₁ =: tanru-unit-2 [linkargs]
tanru-unit-2 ₁₅₂ =: BRIVLA # | GOhA [RAhO] # | KE # selbri-3 /KEhE#/ | ME # sumti /MEhU#/ [MOI #] | (number | lerfu-string) MOI # | NUhA # mex-operator | SE # tanru-unit-2 | JAI # [tag] tanru-unit-2 | any-word (ZEI any-word) ... | NAhE # tanru-unit-2 | NU [NAI] # [joik-jek NU [NAI] #] ... subsentence /KEI#/
linkargs ₁₆₀ =: BE # term [links] /BEhO#/
links ₁₆₁ =: BEI # term [links]
quantifier ₃₀₀ =: number /BOI#/ | VEI # mex /VEhO#/
mex ₃₁₀ =: mex-1 [operator mex-1] ... | FUhA # rp-expression
mex-1 ₃₁₁ =: mex-2 [BIhE # operator mex-1]
mex-2 ₃₁₂ =: operand | [PEhO #] operator mex-2 ... /KUhE#/
rp-expression ₃₃₀ =: rp-operand rp-operand operator
rp-operand ₃₃₂ =: operand | rp-expression
operator ₃₇₀ =: operator-1 [joik-jek operator-1 | joik [stag] KE # operator /KEhE#/] ...
operator-1 ₃₇₁ =: operator-2 | guhek operator-1 gik operator-2 | operator-2 (jek | joik) [stag] BO # operator-1
operator-2 ₃₇₂ =: mex-operator | KE # operator /KEhE#/
mex-operator ₃₇₄ =: SE # mex-operator | NAhE # mex-operator | MAhO # mex /TEhU#/ | NAhU # selbri /TEhU#/ | VUhU #
operand ₃₈₁ =: operand-1 [(ek | joik) [stag] KE # operand /KEhE#/]
operand-1 ₃₈₂ =: operand-2 [joik-ek operand-2] ...
operand-2 ₃₈₃ =: operand-3 [(ek | joik) [stag] BO # operand-2]
operand-3 ₃₈₅ =: quantifier | lerfu-string /BOI#/ | NIhE # selbri /TEhU#/ | MOhE # sumti /TEhU#/ | JOhI # mex-2 ... /TEhU#/ | gek operand gik operand-3 | (LAhE # | NAhE BO #) operand /LUhU#/
number ₈₁₂ =: PA [PA | lerfu-word] ...
lerfu-string ₈₁₇ =: lerfu-word [PA | lerfu-word] ...
lerfu-word ₉₈₇ =: BY | any-word BU | LAU lerfu-word | TEI lerfu-string FOI
ek ₈₀₂ =: [NA] [SE] A [NAI]
gihek ₈₁₈ =: [NA] [SE] GIhA [NAI]
jek ₈₀₅ =: [NA] [SE] JA [NAI]
joik ₈₀₆ =: [SE] JOI [NAI] | interval | GAhO interval GAhO
interval ₉₃₂ =: [SE] BIhI [NAI]
joik-ek ₄₂₁ =: joik # | ek #
joik-jek ₄₂₂ =: joik # | jek #
gek ₈₀₇ =: [SE] GA [NAI] # | joik GI # | stag gik
guhek ₈₀₈ =: [SE] GUhA [NAI] #
gik ₈₁₆ =: GI [NAI] #
tag ₄₉₁ =: tense-modal [joik-jek tense-modal] ...
stag ₉₇₁ =: simple-tense-modal [(jek | joik) simple-tense-modal] ...
tense-modal ₈₁₅ =: simple-tense-modal # | FIhO # selbri /FEhU#/
simple-tense-modal ₉₇₂ =: [NAhE] [SE] BAI [NAI] [KI] | [NAhE] (time [space] | space [time]) & CAhA [KI] | KI | CUhE
time ₁₀₃₀ =: ZI & time-offset ... & (ZEhA [PU [NAI]]) & interval-property ...
time-offset ₁₀₃₃ =: PU [NAI] [ZI]
space ₁₀₄₀ =: VA & space-offset ... & space-interval & (MOhI space-offset)
space-offset ₁₀₄₅ =: FAhA [NAI] [VA]
space-interval ₁₀₄₆ =: ((VEhA & VIhA) [FAhA [NAI]]) & space-int-props
space-int-props ₁₀₄₉ =: (FEhE interval-property) ...
interval-property ₁₀₅₁ =: number ROI [NAI] | TAhE [NAI] | ZAhO [NAI]
free ₃₂ =: SEI # [terms [CU #]] selbri /SEhU/ | SOI # sumti [sumti] /SEhU/ | vocative [relative-clauses] selbri [relative-clauses] /DOhU/ | vocative [relative-clauses] CMEVLA ... # [relative-clauses] /DOhU/ | vocative [sumti] /DOhU/ | (number | lerfu-string) MAI | TO text /TOI/ | XI # (number | lerfu-string) /BOI/ | XI # VEI # mex /VEhO/
vocative ₄₁₅ =: (COI [NAI]) ... & DOI
indicators ₄₁₁ =: [FUhE] indicator ...
indicator ₄₁₃ =: (UI | CAI) [NAI] | Y | DAhO | FUhO

The following rules are non-formal:

word ₁₁₀₀ =: [BAhE] any-word [indicators]
any-word =: “any single word (no compound cmavo)”
anything =: “any text at all, whether Lojban or not”
null ₁₁₀₁ =: any-word SI | utterance SA | text SU

FAhO is a universal terminator and signals the end of parsable input.